imported>Sohmenl at 09:05, 30 October 2025

2025-10-30T09:05:15Z

New page

===Architekten mit allen wichtigen Informationen===
{{SPARQL|query=#title: Architekten mit allen wichtigen Informationen

SELECT DISTINCT ?architect ?architectLabel ?image ?GND ?wikidata ?birthDate ?deathDate ?archive ?archiveLabel WHERE {
?architect tibt:P1 tib:Q5.
?architect tibt:P121 tib:Q1970.
OPTIONAL{?architect tibt:P205 ?image.}
OPTIONAL{?architect tibt:P102 ?GND.}
OPTIONAL{?architect tibt:P104 ?wikidata.}
OPTIONAL{?architect tibt:P201 ?birthDate.}
FILTER ( datatype(?birthDate) = xsd:dateTime )
OPTIONAL{?architect tibt:P202 ?deathDate.}
FILTER ( datatype(?deathDate) = xsd:dateTime )
OPTIONAL{?architect tibt:P204 ?archive.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
ORDER BY ?architect
}}

===Alle Archive die mindestens einen Architekten archivieren und deren Anzahl===
{{SPARQL|query=#title: Alle Archive die mindestens einen Architekten archivieren und deren Anzahl

SELECT DISTINCT ?archive ?archiveLabel (COUNT (?item) AS ?architectCount) WHERE {
?item tibt:P204 ?archive.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
GROUP BY ?archive ?archiveLabel
}}

===Zeitstrahl Architekten===
{{SPARQL|query=#title: Zeitstrahl Architekten
#defaultView:Timeline
SELECT ?architect ?architectLabel ?birthDate WHERE {
?architect tibt:P121 tib:Q1970.
?architect tibt:P201 ?birthDate.
FILTER ( datatype(?birthDate) = xsd:dateTime )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
}}

===Alle Berufe mit Häufigkeit===
{{SPARQL|query=#title: Alle Berufe mit Häufigkeit
SELECT DISTINCT ?occupation ?occupationLabel (COUNT (?person) as ?occupationCount) WHERE {
?person tibt:P121 ?occupation.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
GROUP BY ?occupation ?occupationLabel

}}

===Karte mit Gebäuden===
{{SPARQL|query=#title:Karte mit Bauten
#defaultView:Map

SELECT ?item ?itemLabel ?architect ?architectLabel ?location WHERE {
?item tibt:P207 ?architect ;
tibt:P37 ?location .

SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
}}

===30 früheste Architekten===
{{SPARQL|query=#title: 30 früheste Architekten
SELECT ?architect ?architectLabel (YEAR(?birth) AS ?birth) (YEAR(?death) AS ?death) WHERE {
?architect tibt:P201 ?birth;
tibt:P202 ?death.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
ORDER BY ?birth
LIMIT 30
}}

===Alle weiblichen Fotografen===
{{SPARQL|query=#title: Alle weiblichen Fotografen
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT DISTINCT ?architect ?architectLabel ?wikidataIRI WHERE {
?architect tibt:P104 ?wikidataID ;
tibt:P121 tib:Q1992 .
BIND(IRI(CONCAT("http://www.wikidata.org/entity/", ?wikidataID)) AS ?wikidataIRI)
SERVICE <https://query.wikidata.org/sparql> {
?wikidataIRI wdt:P21 wd:Q6581072 .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
}}

===Bilder von Gebäuden===
{{SPARQL|query=#title: Bilder von Gebäuden
#defaultView:ImageGrid
SELECT DISTINCT ?item ?itemLabel ?image WHERE {
?item tibt:P1 tib:Q2024 ;
tibt:P205 ?image .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
}}

===Die 20 jüngsten Personen mit Geburtsdatum, Wikidata ID, GND ID===
{{SPARQL|query=#title:Die 20 jüngsten Personen mit Geburtsdatum, Wikidata ID, GND ID
SELECT ?item ?itemLabel ?image
(SAMPLE(?birth) AS ?birth)
?wiki ?gnd
WHERE {
?item tibt:P1 tib:Q5 ;
tibt:P205 ?image ;
tibt:P201 ?birth ;
tibt:P104 ?wikiID ;
tibt:P102 ?gndID .
BIND(IRI(CONCAT("http://www.wikidata.org/entity/", ?wikiID)) AS ?wiki)
BIND(IRI(CONCAT("https://d-nb.info/gnd/", ?gndID)) AS ?gnd)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
GROUP BY ?item ?itemLabel ?image ?wiki ?gnd
ORDER BY DESC(?birth)
LIMIT 20
}}

===Architekten mit den Stylen ihrer berühmten Werke===
{{SPARQL|query=#title: Architekten mit den Stylen ihrer berühmten Werke

PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT DISTINCT ?styleLabel ?itemLabel ?item ?wd_id WHERE {
?item tibt:P104 ?wikidataID ;
tibt:P1 tib:Q5 .
BIND(IRI(CONCAT("http://www.wikidata.org/entity/", ?wikidataID)) AS ?wd_id)
SERVICE <https://query.wikidata.org/sparql> {
?wd_id wdt:P800 ?notableWork.
?notableWork wdt:P149 ?style .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
BIND(?styleLabel AS ?styleLabel)
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
ORDER BY ?itemLabel
}}

===Graph aus Architekten und Gebäuden===
{{SPARQL|query=#title: Graph aus Architekten und Gebäuden
#defaultView:Graph
SELECT DISTINCT ?item ?itemLabel ?image ?architect ?architectLabel ?architectimage WHERE {
?item tibt:P1 tib:Q2024 ;
tibt:P207 ?architect ;
tibt:P205 ?image .
?architect tibt:P205 ?architectimage .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
ORDER BY ?item
}}

Query/Examples - Revision history

imported>Sohmenl at 09:05, 30 October 2025